QNMs of a d-dimensional SAdS black holes

Spacetime:

de = 4; l = 0; rplus = 100; h = 1/rplus; 
        r0 = (h^(-de + 1) + 
                h^(-de + 3))^(1/(de - 3));

Horowitz and Hubeny's functions (3.2)-(3.4):

s = 
      Function[x, (r0^(de - 3)*x^(de + 1) - x^4 - x^2)/(x - 
              h)]; t = 
      Function[{x, w}, (de - 1) r0^(de - 3) x^de - 2 x^3 - 
          2 x^2 I w]; 
    V = Function[x, 
        de*(de - 2)/4 + (de - 2)*(de - 4)*x^2/4 + 
          l*(l + de - 3)*x^2 + (de - 2)^2*r0^(de - 3)/4*
            x^(de - 1)]; u = Function[x, (x - h) V[x]];

Extracting coefficients of expansion of s, t u, around the horizon:

coeficienteDeS = 
      Function[n, SeriesCoefficient[Series[s[x], {x, h, n}], n]]; 
    coeficienteDeU = 
      Function[n, SeriesCoefficient[Series[u[x], {x, h, n}], n]]; 
    coeficienteDeT = 
      Function[n, SeriesCoefficient[Series[t[x, w], {x, h, n}], n]]; 
    P = Function[{n, w}, 
        n*(n - 1)*coeficienteDeS[0] + n*coeficienteDeT[0]];

Initialization and maximum number of iterations:

a[0] = 1; Nit = 40; 
    a[n_] := a[n] = 
        Simplify[-1/
              P[n, w] Sum[(j (j - 1) coeficienteDeS[n - j]  +  
                    j coeficienteDeT[n - j] + coeficienteDeU[n - j]) 
                a[j], {j, 0, n - 1}]]; 
    ex[n_] := ex[n] = Sum[a[i]*(-h)^i, {i, 0, n}];

Final result

expressao = 
      Sum[a[i]*(-h)^(i), {i, 0, 
          Nit}]; {l, FindRoot[expressao == 0, {w, 180 - 260*I}, 
            AccuracyGoal -> 7][[1]][[2]]}

References

[1] G .  T .  Horowitz and V .  E .  
          Hubeny,  
"Quasinormal modes of AdS black \
holes and the approach to thermal equilibrium", 
      Phys .  Rev .   D62 : 
          024027 (2000) [arXiv : hep - th/9909056].

[2] 
        V .  Cardoso and J .  P .  S .  
          Lemos, "Quasi-normal modes of Schwarzschild anti-de Sitter black \
holes: Electromagnetic and gravitational perturbations,"
Phys .  Rev .  D 64 : 
        084017 (2001) [arXiv : gr - qc/0105103].

[3] V .  Cardoso,R .  Konoplya and J .  P .  S .  Lemos,\
Phys . 
        Rev .   D68 : 
          044024 (2003) [arXiv : gr - qc/0305037].